head	1.14;
access;
symbols
	LMTP2NNTP_1_4_1:1.14
	LMTP2NNTP_1_4_0:1.14
	VAR_1_1_3:1.14
	VAR_1_1_2:1.13
	VAR_1_1_1:1.13
	LMTP2NNTP_1_3_0:1.13
	LMTP2NNTP_1_3b2:1.13
	LMTP2NNTP_1_3b1:1.13
	LMTP2NNTP_1_3a3:1.13
	LMTP2NNTP_1_3a2:1.13
	LMTP2NNTP_1_3a1:1.13
	VAR_1_1_0:1.13
	VAR_1_0_0:1.8
	LMTP2NNTP_1_2_0:1.7
	LMTP2NNTP_1_2b4:1.7
	LMTP2NNTP_1_2b3:1.7
	LMTP2NNTP_1_2b2:1.7
	LMTP2NNTP_1_2b1:1.7
	LMTP2NNTP_1_2a8:1.7
	LMTP2NNTP_1_2a7:1.7
	LMTP2NNTP_1_2a6:1.7
	LMTP2NNTP_1_2a5:1.7
	LMTP2NNTP_1_2a4:1.7
	VAR_0_9_0:1.5
	LMTP2NNTP_1_2a3:1.3
	OSSP_RC_SPEC:1.1;
locks; strict;
comment	@# @;


1.14
date	2005.01.20.20.29.06;	author rse;	state Exp;
branches;
next	1.13;

1.13
date	2004.04.04.10.00.05;	author rse;	state Exp;
branches;
next	1.12;

1.12
date	2004.04.04.09.59.53;	author rse;	state Exp;
branches;
next	1.11;

1.11
date	2004.04.04.09.57.10;	author rse;	state Exp;
branches;
next	1.10;

1.10
date	2004.04.04.08.07.34;	author rse;	state Exp;
branches;
next	1.9;

1.9
date	2004.04.04.08.04.34;	author rse;	state Exp;
branches;
next	1.8;

1.8
date	2003.02.14.21.17.07;	author rse;	state Exp;
branches;
next	1.7;

1.7
date	2002.03.13.18.19.54;	author rse;	state Exp;
branches;
next	1.6;

1.6
date	2002.03.09.19.39.57;	author rse;	state Exp;
branches;
next	1.5;

1.5
date	2002.03.08.12.55.52;	author rse;	state Exp;
branches;
next	1.4;

1.4
date	2002.03.07.10.20.40;	author rse;	state Exp;
branches;
next	1.3;

1.3
date	2002.02.28.08.48.44;	author rse;	state Exp;
branches;
next	1.2;

1.2
date	2002.02.27.13.44.16;	author rse;	state Exp;
branches;
next	1.1;

1.1
date	2002.01.30.19.37.14;	author rse;	state Exp;
branches;
next	;


desc
@@


1.14
log
@Bumped year in copyright messages for new year 2005
@
text
@dnl ##
dnl ##  OSSP var -- Variable Expansion
dnl ##  Copyright (c) 2001-2005 Ralf S. Engelschall <rse@@engelschall.com>
dnl ##  Copyright (c) 2001-2005 The OSSP Project <http://www.ossp.org/>
dnl ##  Copyright (c) 2001-2005 Cable & Wireless <http://www.cw.com/>
dnl ##
dnl ##  This file is part of OSSP var, a variable expansion
dnl ##  library which can be found at http://www.ossp.org/pkg/lib/var/.
dnl ##
dnl ##  Permission to use, copy, modify, and distribute this software for
dnl ##  any purpose with or without fee is hereby granted, provided that
dnl ##  the above copyright notice and this permission notice appear in all
dnl ##  copies.
dnl ##
dnl ##  THIS SOFTWARE IS PROVIDED ``AS IS'' AND ANY EXPRESSED OR IMPLIED
dnl ##  WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF
dnl ##  MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
dnl ##  IN NO EVENT SHALL THE AUTHORS AND COPYRIGHT HOLDERS AND THEIR
dnl ##  CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
dnl ##  SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
dnl ##  LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF
dnl ##  USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
dnl ##  ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
dnl ##  OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT
dnl ##  OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
dnl ##  SUCH DAMAGE.
dnl ##
dnl ##  aclocal.m4: GNU Autoconf local macro definitions
dnl ##

AC_DEFUN(EN_PROG_CC,[dnl
  AC_PROG_CC
  AC_PROG_CC_STDC
  if test ".$ac_cv_prog_cc_stdc" = .no; then
      AC_MSG_ERROR([require an ANSI/ISO C compliant compiler])
  fi
])

dnl ##
dnl ##  Check whether compiler option works
dnl ##
dnl ##  configure.in:
dnl ##    AC_COMPILER_OPTION(<name>, <display>, <option>,
dnl ##                       <action-success>, <action-failure>)
dnl ##

AC_DEFUN(AC_COMPILER_OPTION,[dnl
AC_MSG_CHECKING(whether compiler option(s) $2 work)
AC_CACHE_VAL(ac_cv_compiler_option_$1,[
SAVE_CFLAGS="$CFLAGS"
CFLAGS="$CFLAGS $3"
AC_TRY_COMPILE([],[], ac_cv_compiler_option_$1=yes, ac_cv_compiler_option_$1=no)
CFLAGS="$SAVE_CFLAGS"
])dnl
if test ".$ac_cv_compiler_option_$1" = .yes; then
    ifelse([$4], , :, [$4])
else
    ifelse([$5], , :, [$5])
fi
AC_MSG_RESULT([$ac_cv_compiler_option_$1])
])dnl

dnl ##
dnl ##  Debugging Support
dnl ##
dnl ##  configure.in:
dnl ##    AC_CHECK_DEBUGGING
dnl ##

AC_DEFUN(AC_CHECK_DEBUGGING,[dnl
AC_ARG_ENABLE(debug,dnl
[  --enable-debug          build for debugging (default=no)],
[dnl
if test ".$ac_cv_prog_gcc" = ".yes"; then
    case "$CFLAGS" in
        *-O* ) ;;
           * ) CFLAGS="$CFLAGS -O2" ;;
    esac
    case "$CFLAGS" in
        *-g* ) ;;
           * ) CFLAGS="$CFLAGS -g" ;;
    esac
    case "$CFLAGS" in
        *-pipe* ) ;;
              * ) AC_COMPILER_OPTION(pipe, -pipe, -pipe, CFLAGS="$CFLAGS -pipe") ;;
    esac
    AC_COMPILER_OPTION(defdbg, -DDEBUG, -DDEBUG, CFLAGS="$CFLAGS -DDEBUG")
    CFLAGS="$CFLAGS -pedantic"
    CFLAGS="$CFLAGS -Wall"
    WMORE="-Wshadow -Wpointer-arith -Wcast-align -Winline"
    WMORE="$WMORE -Wmissing-prototypes -Wmissing-declarations -Wnested-externs"
    AC_COMPILER_OPTION(wmore, -W<xxx>, $WMORE, CFLAGS="$CFLAGS $WMORE")
    AC_COMPILER_OPTION(wnolonglong, -Wno-long-long, -Wno-long-long, CFLAGS="$CFLAGS -Wno-long-long")
else
    case "$CFLAGS" in
        *-g* ) ;;
           * ) CFLAGS="$CFLAGS -g" ;;
    esac
fi
msg="enabled"
],[
if test ".$ac_cv_prog_gcc" = ".yes"; then
case "$CFLAGS" in
    *-pipe* ) ;;
          * ) AC_COMPILER_OPTION(pipe, -pipe, -pipe, CFLAGS="$CFLAGS -pipe") ;;
esac
fi
case "$CFLAGS" in
    *-g* ) CFLAGS=`echo "$CFLAGS" |\
                   sed -e 's/ -g / /g' -e 's/ -g$//' -e 's/^-g //g' -e 's/^-g$//'` ;;
esac
case "$CXXFLAGS" in
    *-g* ) CXXFLAGS=`echo "$CXXFLAGS" |\
                     sed -e 's/ -g / /g' -e 's/ -g$//' -e 's/^-g //g' -e 's/^-g$//'` ;;
esac
msg=disabled
])dnl
AC_MSG_CHECKING(for compilation debug mode)
AC_MSG_RESULT([$msg])
if test ".$msg" = .enabled; then
    enable_shared=no
fi
])

dnl ##
dnl ##  Check for an external/extension library.
dnl ##  - is aware of <libname>-config style scripts
dnl ##  - searches under standard paths include, lib, etc.
dnl ##  - searches under subareas like .libs, etc.
dnl ##
dnl ##  configure.in:
dnl ##      AC_CHECK_EXTLIB(<realname>, <libname>, <func>, <header>,
dnl ##                      [<success-action> [, <fail-action>]])
dnl ##  Makefile.in:
dnl ##      CFLAGS  = @@CFLAGS@@
dnl ##      LDFLAGS = @@LDFLAGS@@
dnl ##      LIBS    = @@LIBS@@
dnl ##  shell:
dnl ##      $ ./configure --with-<libname>[=DIR]
dnl ##

AC_DEFUN(AC_CHECK_EXTLIB,[dnl
AC_ARG_WITH($2, [dnl
[  --with-]m4_substr([$2[[=DIR]]                     ], 0, 19)[build with external $1 library (default=no)]], [dnl
    if test ".$with_$2" = .yes; then
        #   via config script in PATH
        $2_version=`($2-config --version) 2>/dev/null`
        if test ".$$2_version" != .; then
            CPPFLAGS="$CPPFLAGS `$2-config --cflags`"
            CFLAGS="$CFLAGS `$2-config --cflags`"
            LDFLAGS="$LDFLAGS `$2-config --ldflags`"
        fi
    else
        if test -d "$with_$2"; then
            found=0
            #   via config script
            for dir in $with_$2/bin $with_$2; do
                if test -f "$dir/$2-config" && test ! -f "$dir/$2-config.in"; then
                    $2_version=`($dir/$2-config --version) 2>/dev/null`
                    if test ".$$2_version" != .; then
                        CPPFLAGS="$CPPFLAGS `$dir/$2-config --cflags`"
                        CFLAGS="$CFLAGS `$dir/$2-config --cflags`"
                        LDFLAGS="$LDFLAGS `$dir/$2-config --ldflags`"
                        found=1
                        break
                    fi
                fi
            done
            #   in standard sub-areas
            if test ".$found" = .0; then
                for dir in $with_$2/include/$2 $with_$2/include $with_$2; do
                    if test -f "$dir/$4"; then
                        CPPFLAGS="$CPPFLAGS -I$dir"
                        CFLAGS="$CFLAGS -I$dir"
                        found=1
                        break
                    fi
                done
                for dir in $with_$2/lib/$2 $with_$2/lib $with_$2; do
                    if test -f "$dir/lib$2.la" && test -d "$dir/.libs"; then
                        LDFLAGS="$LDFLAGS -L$dir -L$dir/.libs"
                        found=1
                        break
                    elif test -f "$dir/lib$2.a" || test -f "$dir/lib$2.so"; then
                        LDFLAGS="$LDFLAGS -L$dir"
                        found=1
                        break
                    fi
                done
            fi
            #   in any sub-area
            if test ".$found" = .0; then
changequote(, )dnl
                for file in x `find $with_$2 -name "$4" -type f -print`; do
                    test .$file = .x && continue
                    dir=`echo $file | sed -e 's;[^/]*$;;' -e 's;\(.\)/$;\1;'`
                    CPPFLAGS="$CPPFLAGS -I$dir"
                    CFLAGS="$CFLAGS -I$dir"
                done
                for file in x `find $with_$2 -name "lib$2.[aso]" -type f -print`; do
                    test .$file = .x && continue
                    dir=`echo $file | sed -e 's;[^/]*$;;' -e 's;\(.\)/$;\1;'`
                    LDFLAGS="$LDFLAGS -L$dir"
                done
changequote([, ])dnl
            fi
        fi
    fi
    AC_HAVE_HEADERS($4)
    AC_CHECK_LIB($2, $3)
    with_$2=yes
    ac_var="ac_cv_header_`echo $4 | sed 'y%./+-%__p_%'`"
    eval "ac_val=\$$ac_var"
    if test ".$ac_val" != .yes; then
        with_$2=no
    fi
    if test ".$ac_cv_lib_$2_$3" != .yes; then
        with_$2=no
    fi
    if test ".$with_$2" = .no; then
        AC_ERROR([Unable to find $1 library])
    fi
    ], [dnl
if test ".$with_$2" = .; then
    with_$2=no
fi
    ])dnl
AC_MSG_CHECKING(whether to build against external $1 library)
if test ".$with_$2" = .yes; then
    ifelse([$5], , :, [$5])
else
    ifelse([$6], , :, [$6])
fi
AC_MSG_RESULT([$with_$2])
])dnl

dnl ##
dnl ##  Check for C99 va_copy() implementation
dnl ##  (and provide fallback implementation if neccessary)
dnl ##
dnl ##  configure.in:
dnl ##    AC_CHECK_VA_COPY
dnl ##  foo.c:
dnl ##    #include "config.h"
dnl ##    [...]
dnl ##    va_copy(d,s)
dnl ##
dnl ##  This check is rather complex: first because we really have to
dnl ##  try various possible implementations in sequence and second, we
dnl ##  cannot define a macro in config.h with parameters directly.
dnl ##

dnl #   test program for va_copy() implementation
changequote(<<,>>)
m4_define(__va_copy_test, <<[
#include <stdlib.h>
#include <stdarg.h>
#include <string.h>
#define DO_VA_COPY(d, s) $1
void test(char *str, ...)
{
    va_list ap, ap2;
    int i;
    va_start(ap, str);
    DO_VA_COPY(ap2, ap);
    for (i = 1; i <= 9; i++) {
        int k = (int)va_arg(ap, int);
        if (k != i)
            abort();
    }
    DO_VA_COPY(ap, ap2);
    for (i = 1; i <= 9; i++) {
        int k = (int)va_arg(ap, int);
        if (k != i)
            abort();
    }
    va_end(ap);
}
int main(int argc, char *argv[])
{
    test("test", 1, 2, 3, 4, 5, 6, 7, 8, 9);
    exit(0);
}
]>>)
changequote([,])

dnl #   test driver for va_copy() implementation
m4_define(__va_copy_check, [
    AH_VERBATIM($1,
[/* Predefined possible va_copy() implementation (id: $1) */
#define __VA_COPY_USE_$1(d, s) $2])
    if test ".$ac_cv_va_copy" = .; then
        AC_TRY_RUN(__va_copy_test($2), [ac_cv_va_copy="$1"])
    fi
])

dnl #   Autoconf check for va_copy() implementation checking
AC_DEFUN(AC_CHECK_VA_COPY,[
  dnl #   provide Autoconf display check message
  AC_MSG_CHECKING(for va_copy() function)
  dnl #   check for various implementations in priorized sequence   
  AC_CACHE_VAL(ac_cv_va_copy, [
    ac_cv_va_copy=""
    dnl #   1. check for standardized C99 macro
    __va_copy_check(C99, [va_copy((d), (s))])
    dnl #   2. check for alternative/deprecated GCC macro
    __va_copy_check(GCM, [VA_COPY((d), (s))])
    dnl #   3. check for internal GCC macro (high-level define)
    __va_copy_check(GCH, [__va_copy((d), (s))])
    dnl #   4. check for internal GCC macro (built-in function)
    __va_copy_check(GCB, [__builtin_va_copy((d), (s))])
    dnl #   5. check for assignment approach (assuming va_list is a struct)
    __va_copy_check(ASS, [do { (d) = (s); } while (0)])
    dnl #   6. check for assignment approach (assuming va_list is a pointer)
    __va_copy_check(ASP, [do { *(d) = *(s); } while (0)])
    dnl #   7. check for memory copying approach (assuming va_list is a struct)
    __va_copy_check(CPS, [memcpy((void *)&(d), (void *)&(s)), sizeof((s))])
    dnl #   8. check for memory copying approach (assuming va_list is a pointer)
    __va_copy_check(CPP, [memcpy((void *)(d), (void *)(s)), sizeof(*(s))])
    if test ".$ac_cv_va_copy" = .; then
        AC_ERROR([no working implementation found])
    fi
  ])
  dnl #   optionally activate the fallback implementation
  if test ".$ac_cv_va_copy" = ".C99"; then
      AC_DEFINE(HAVE_VA_COPY, 1, [Define if va_copy() macro exists (and no fallback implementation is required)])
  fi
  dnl #   declare which fallback implementation to actually use
  AC_DEFINE_UNQUOTED([__VA_COPY_USE], [__VA_COPY_USE_$ac_cv_va_copy],
      [Define to id of used va_copy() implementation])
  dnl #   provide activation hook for fallback implementation
  AH_VERBATIM([__VA_COPY_ACTIVATION],
[/* Optional va_copy() implementation activation */
#ifndef HAVE_VA_COPY
#define va_copy(d, s) __VA_COPY_USE(d, s)
#endif
])
  dnl #   provide Autoconf display result message
  if test ".$ac_cv_va_copy" = ".C99"; then
      AC_MSG_RESULT([yes])
  else
      AC_MSG_RESULT([no (using fallback implementation)])
  fi
])

@


1.13
log
@fix check
@
text
@d3 3
a5 3
dnl ##  Copyright (c) 2001-2004 Ralf S. Engelschall <rse@@engelschall.com>
dnl ##  Copyright (c) 2001-2004 The OSSP Project <http://www.ossp.org/>
dnl ##  Copyright (c) 2001-2004 Cable & Wireless <http://www.cw.com/>
@


1.12
log
@fix check
@
text
@d339 1
a339 1
  if test ".$ac_cv_va_copy" = ".STD"; then
@


1.11
log
@flush more pending changes after some more platform checks
@
text
@d325 1
a325 1
  if test ".$ac_cv_va_copy" = ".STD"; then
@


1.10
log
@adjust copyrights
@
text
@d291 1
a291 1
#define __VA_COPY_USE_$1 $2])
d305 1
a305 1
    __va_copy_check(STD, [va_copy((d), (s))])
d307 13
a319 9
    __va_copy_check(MAC, [VA_COPY((d), (s))])
    dnl #   3. check for assignment approach (assuming va_list is a struct)
    __va_copy_check(AS1, [do { (d) = (s); } while (0)])
    dnl #   4. check for assignment approach (assuming va_list is a pointer)
    __va_copy_check(AS2, [do { *(d) = *(s); } while (0)])
    dnl #   5. check for memory copying approach (assuming va_list is a struct)
    __va_copy_check(CP1, [memcpy((void *)&(d), (void *)&(s)), sizeof((s))])
    dnl #   6. check for memory copying approach (assuming va_list is a pointer)
    __va_copy_check(CP2, [memcpy((void *)(d), (void *)(s)), sizeof(*(s))])
@


1.9
log
@Provide Autoconf check (AC_CHECK_VA_COPY) for va_copy(d,s) macro
and fallback implementations and now that we can be sure that
va_copy() exists for us, use it in var_formatv() and ts.c instead
of the direct assignments (which are not sufficiently portable).
@
text
@d3 3
a5 3
dnl ##  Copyright (c) 2001-2003 Ralf S. Engelschall <rse@@engelschall.com>
dnl ##  Copyright (c) 2001-2003 The OSSP Project <http://www.ossp.org/>
dnl ##  Copyright (c) 2001-2003 Cable & Wireless Deutschland <http://www.cw.com/de/>
@


1.8
log
@final polishing for release 1.0.0
@
text
@d237 104
@


1.7
log
@fix naming
@
text
@d3 3
a5 3
dnl ##  Copyright (c) 2001-2002 Ralf S. Engelschall <rse@@engelschall.com>
dnl ##  Copyright (c) 2001-2002 The OSSP Project <http://www.ossp.org/>
dnl ##  Copyright (c) 2001-2002 Cable & Wireless Deutschland <http://www.cw.com/de/>
@


1.6
log
@require an ISO-C compliant compiler
@
text
@d2 1
a2 1
dnl ##  OSSP val -- Variable Expansion
d8 1
a8 1
dnl ##  which can be found at http://www.ossp.org/pkg/lib/var/.
@


1.5
log
@polishing and copyright extension (add natural person)
@
text
@d31 8
@


1.4
log
@do not use this old gdb3 stuff any longer
@
text
@d3 1
@


1.3
log
@URL fixing and additional documents
@
text
@a78 1
    AC_COMPILER_OPTION(ggdb3, -ggdb3, -ggdb3, CFLAGS="$CFLAGS -ggdb3")
@


1.2
log
@style and text cleanups
@
text
@d7 1
a7 1
dnl ##  which can be found at http://www.ossp.org/pkg/var/.
@


1.1
log
@add optional OSSP ex based exception handling support
@
text
@d2 3
a4 4
dnl ##  val - OSSP Value Library
dnl ##  Copyright (c) 2002 Ralf S. Engelschall <rse@@engelschall.com>
dnl ##  Copyright (c) 2002 The OSSP Project <http://www.ossp.org/>
dnl ##  Copyright (c) 2002 Cable & Wireless Deutschland <http://www.cw.com/de/>
d6 2
a7 2
dnl ##  This file is part of OSSP val, a Value library which
dnl ##  can be found at http://www.ossp.org/pkg/val/.
@