head	1.11;
access;
symbols
	EX_1_0_6:1.10
	LMTP2NNTP_1_4_1:1.8
	LMTP2NNTP_1_4_0:1.8
	EX_1_0_5:1.8
	LMTP2NNTP_1_3_0:1.6
	LMTP2NNTP_1_3b2:1.6
	LMTP2NNTP_1_3b1:1.6
	LMTP2NNTP_1_3a3:1.6
	LMTP2NNTP_1_3a2:1.6
	LMTP2NNTP_1_3a1:1.6
	EX_1_0_4:1.6
	EX_1_0_3:1.5
	OSSP_RC_0_7_3:1.4
	OSSP_RC_0_7_2:1.4
	OSSP_RC_0_7_1:1.4
	OSSP_RC_ALPHA_06:1.4
	OSSP_RC_EXBROKEN:1.4
	LMTP2NNTP_1_2_0:1.4
	LMTP2NNTP_1_2b4:1.4
	LMTP2NNTP_1_2b3:1.4
	LMTP2NNTP_1_2b2:1.4
	LMTP2NNTP_1_2b1:1.4
	LMTP2NNTP_1_2a8:1.4
	LMTP2NNTP_1_2a7:1.4
	EX_1_0_2:1.4
	EX_1_0_1:1.3
	LMTP2NNTP_1_2a6:1.2
	LMTP2NNTP_1_2a5:1.2
	EX_1_0_0:1.2
	LMTP2NNTP_1_2a4:1.1
	EX_0_9_1:1.1
	LMTP2NNTP_1_2a3:1.1
	EX_0_9_0:1.1;
locks; strict;
comment	@# @;


1.11
date	2007.10.12.21.00.45;	author rse;	state Exp;
branches;
next	1.10;
commitid	Qug54U8ITj2rslBs;

1.10
date	2007.10.12.19.59.57;	author rse;	state Exp;
branches;
next	1.9;
commitid	9SN7ivPOxnsC7lBs;

1.9
date	2006.08.10.19.49.33;	author rse;	state Exp;
branches;
next	1.8;
commitid	o4A6XFppdzD0PkIr;

1.8
date	2005.01.30.13.41.11;	author rse;	state Exp;
branches;
next	1.7;

1.7
date	2005.01.30.13.39.07;	author rse;	state Exp;
branches;
next	1.6;

1.6
date	2004.04.05.14.44.21;	author rse;	state Exp;
branches;
next	1.5;

1.5
date	2004.03.25.19.01.42;	author rse;	state Exp;
branches;
next	1.4;

1.4
date	2003.01.30.11.04.42;	author rse;	state Exp;
branches;
next	1.3;

1.3
date	2003.01.06.15.31.24;	author rse;	state Exp;
branches;
next	1.2;

1.2
date	2002.03.30.19.04.59;	author rse;	state Exp;
branches;
next	1.1;

1.1
date	2002.01.26.20.12.19;	author rse;	state Exp;
branches;
next	;


desc
@@


1.11
log
@Fix __VA_COPY_USE_{CSP,CPP} fallback macros for va_copy.

Submitted by: Mark A. Lindner <mark.a.lindner@@gmail.com>
@
text
@dnl ##
dnl ##  OSSP ex - Exception Handling
dnl ##  Copyright (c) 2002-2007 Ralf S. Engelschall <rse@@engelschall.com>
dnl ##  Copyright (c) 2002-2007 The OSSP Project <http://www.ossp.org/>
dnl ##
dnl ##  This file is part of OSSP ex, an exception handling library
dnl ##  which can be found at http://www.ossp.org/pkg/lib/ex/.
dnl ##
dnl ##  Permission to use, copy, modify, and distribute this software for
dnl ##  any purpose with or without fee is hereby granted, provided that
dnl ##  the above copyright notice and this permission notice appear in all
dnl ##  copies.
dnl ##
dnl ##  THIS SOFTWARE IS PROVIDED ``AS IS'' AND ANY EXPRESSED OR IMPLIED
dnl ##  WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF
dnl ##  MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
dnl ##  IN NO EVENT SHALL THE AUTHORS AND COPYRIGHT HOLDERS AND THEIR
dnl ##  CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
dnl ##  SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
dnl ##  LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF
dnl ##  USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
dnl ##  ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
dnl ##  OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT
dnl ##  OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
dnl ##  SUCH DAMAGE.
dnl ##
dnl ##  aclocal.m4: GNU Autoconf local macro definitions
dnl ##

dnl ##
dnl ##  Check whether compiler option works
dnl ##
dnl ##  configure.in:
dnl ##    AC_COMPILER_OPTION(<name>, <display>, <option>,
dnl ##                       <action-success>, <action-failure>)
dnl ##

AC_DEFUN(AC_COMPILER_OPTION,[dnl
AC_MSG_CHECKING(whether compiler option(s) $2 work)
AC_CACHE_VAL(ac_cv_compiler_option_$1,[
SAVE_CFLAGS="$CFLAGS"
CFLAGS="$CFLAGS $3"
AC_TRY_COMPILE([],[], ac_cv_compiler_option_$1=yes, ac_cv_compiler_option_$1=no)
CFLAGS="$SAVE_CFLAGS"
])dnl
if test ".$ac_cv_compiler_option_$1" = .yes; then
    ifelse([$4], , :, [$4])
else
    ifelse([$5], , :, [$5])
fi
AC_MSG_RESULT([$ac_cv_compiler_option_$1])
])dnl

dnl ##
dnl ##  Debugging Support
dnl ##
dnl ##  configure.in:
dnl ##    AC_CHECK_DEBUGGING
dnl ##

AC_DEFUN(AC_CHECK_DEBUGGING,[dnl
AC_ARG_ENABLE(debug,dnl
[  --enable-debug          build for debugging (default=no)],
[dnl
if test ".$ac_cv_prog_gcc" = ".yes"; then
    case "$CFLAGS" in
        *-O* ) ;;
           * ) CFLAGS="$CFLAGS -O2" ;;
    esac
    case "$CFLAGS" in
        *-g* ) ;;
           * ) CFLAGS="$CFLAGS -g" ;;
    esac
    case "$CFLAGS" in
        *-pipe* ) ;;
              * ) AC_COMPILER_OPTION(pipe, -pipe, -pipe, CFLAGS="$CFLAGS -pipe") ;;
    esac
    AC_COMPILER_OPTION(defdbg, -DDEBUG, -DDEBUG, CFLAGS="$CFLAGS -DDEBUG")
    AC_COMPILER_OPTION(ggdb3, -ggdb3, -ggdb3, CFLAGS="$CFLAGS -ggdb3")
    CFLAGS="$CFLAGS -pedantic"
    CFLAGS="$CFLAGS -Wall"
    WMORE="-Wshadow -Wpointer-arith -Wcast-align -Winline"
    WMORE="$WMORE -Wmissing-prototypes -Wmissing-declarations -Wnested-externs"
    AC_COMPILER_OPTION(wmore, -W<xxx>, $WMORE, CFLAGS="$CFLAGS $WMORE")
    AC_COMPILER_OPTION(wnolonglong, -Wno-long-long, -Wno-long-long, CFLAGS="$CFLAGS -Wno-long-long")
else
    case "$CFLAGS" in
        *-g* ) ;;
           * ) CFLAGS="$CFLAGS -g" ;;
    esac
fi
msg="enabled"
],[
if test ".$ac_cv_prog_gcc" = ".yes"; then
case "$CFLAGS" in
    *-pipe* ) ;;
          * ) AC_COMPILER_OPTION(pipe, -pipe, -pipe, CFLAGS="$CFLAGS -pipe") ;;
esac
fi
case "$CFLAGS" in
    *-g* ) CFLAGS=`echo "$CFLAGS" |\
                   sed -e 's/ -g / /g' -e 's/ -g$//' -e 's/^-g //g' -e 's/^-g$//'` ;;
esac
case "$CXXFLAGS" in
    *-g* ) CXXFLAGS=`echo "$CXXFLAGS" |\
                     sed -e 's/ -g / /g' -e 's/ -g$//' -e 's/^-g //g' -e 's/^-g$//'` ;;
esac
msg=disabled
])dnl
AC_MSG_CHECKING(for compilation debug mode)
AC_MSG_RESULT([$msg])
if test ".$msg" = .enabled; then
    enable_shared=no
fi
])

dnl ##
dnl ##  Check for C99 va_copy() implementation
dnl ##  (and provide fallback implementation if neccessary)
dnl ##
dnl ##  configure.in:
dnl ##    AC_CHECK_VA_COPY
dnl ##  foo.c:
dnl ##    #include "config.h"
dnl ##    [...]
dnl ##    va_copy(d,s)
dnl ##
dnl ##  This check is rather complex: first because we really have to
dnl ##  try various possible implementations in sequence and second, we
dnl ##  cannot define a macro in config.h with parameters directly.
dnl ##

dnl #   test program for va_copy() implementation
changequote(<<,>>)
m4_define(__va_copy_test, <<[
#include <stdlib.h>
#include <stdarg.h>
#include <string.h>
#define DO_VA_COPY(d, s) $1
void test(char *str, ...)
{
    va_list ap, ap2;
    int i;
    va_start(ap, str);
    DO_VA_COPY(ap2, ap);
    for (i = 1; i <= 9; i++) {
        int k = (int)va_arg(ap, int);
        if (k != i)
            abort();
    }
    DO_VA_COPY(ap, ap2);
    for (i = 1; i <= 9; i++) {
        int k = (int)va_arg(ap, int);
        if (k != i)
            abort();
    }
    va_end(ap);
}
int main(int argc, char *argv[])
{
    test("test", 1, 2, 3, 4, 5, 6, 7, 8, 9);
    exit(0);
}
]>>)
changequote([,])

dnl #   test driver for va_copy() implementation
m4_define(__va_copy_check, [
    AH_VERBATIM($1,
[/* Predefined possible va_copy() implementation (id: $1) */
#define __VA_COPY_USE_$1(d, s) $2])
    if test ".$ac_cv_va_copy" = .; then
        AC_TRY_RUN(__va_copy_test($2), [ac_cv_va_copy="$1"])
    fi
])

dnl #   Autoconf check for va_copy() implementation checking
AC_DEFUN(AC_CHECK_VA_COPY,[
  dnl #   provide Autoconf display check message
  AC_MSG_CHECKING(for va_copy() function)
  dnl #   check for various implementations in priorized sequence
  AC_CACHE_VAL(ac_cv_va_copy, [
    ac_cv_va_copy=""
    dnl #   1. check for standardized C99 macro
    __va_copy_check(C99, [va_copy((d), (s))])
    dnl #   2. check for alternative/deprecated GCC macro
    __va_copy_check(GCM, [VA_COPY((d), (s))])
    dnl #   3. check for internal GCC macro (high-level define)
    __va_copy_check(GCH, [__va_copy((d), (s))])
    dnl #   4. check for internal GCC macro (built-in function)
    __va_copy_check(GCB, [__builtin_va_copy((d), (s))])
    dnl #   5. check for assignment approach (assuming va_list is a struct)
    __va_copy_check(ASS, [do { (d) = (s); } while (0)])
    dnl #   6. check for assignment approach (assuming va_list is a pointer)
    __va_copy_check(ASP, [do { *(d) = *(s); } while (0)])
    dnl #   7. check for memory copying approach (assuming va_list is a struct)
    __va_copy_check(CPS, [memcpy((void *)&(d), (void *)&(s), sizeof((s)))])
    dnl #   8. check for memory copying approach (assuming va_list is a pointer)
    __va_copy_check(CPP, [memcpy((void *)(d), (void *)(s), sizeof(*(s)))])
    if test ".$ac_cv_va_copy" = .; then
        AC_ERROR([no working implementation found])
    fi
  ])
  dnl #   optionally activate the fallback implementation
  if test ".$ac_cv_va_copy" = ".C99"; then
      AC_DEFINE(HAVE_VA_COPY, 1, [Define if va_copy() macro exists (and no fallback implementation is required)])
  fi
  dnl #   declare which fallback implementation to actually use
  AC_DEFINE_UNQUOTED([__VA_COPY_USE], [__VA_COPY_USE_$ac_cv_va_copy],
      [Define to id of used va_copy() implementation])
  dnl #   provide activation hook for fallback implementation
  AH_VERBATIM([__VA_COPY_ACTIVATION],
[/* Optional va_copy() implementation activation */
#ifndef HAVE_VA_COPY
#define va_copy(d, s) __VA_COPY_USE(d, s)
#endif
])
  dnl #   provide Autoconf display result message
  if test ".$ac_cv_va_copy" = ".C99"; then
      AC_MSG_RESULT([yes])
  else
      AC_MSG_RESULT([no (using fallback implementation)])
  fi
])

@


1.10
log
@prepare for release
@
text
@d197 1
a197 1
    __va_copy_check(CPS, [memcpy((void *)&(d), (void *)&(s)), sizeof((s))])
d199 1
a199 1
    __va_copy_check(CPP, [memcpy((void *)(d), (void *)(s)), sizeof(*(s))])
@


1.9
log
@cleanup source tree
@
text
@d3 2
a4 2
dnl ##  Copyright (c) 2002-2006 Ralf S. Engelschall <rse@@engelschall.com>
dnl ##  Copyright (c) 2002-2006 The OSSP Project <http://www.ossp.org/>
@


1.8
log
@remove trailing whitespaces
@
text
@d3 2
a4 3
dnl ##  Copyright (c) 2002-2005 Ralf S. Engelschall <rse@@engelschall.com>
dnl ##  Copyright (c) 2002-2005 The OSSP Project <http://www.ossp.org/>
dnl ##  Copyright (c) 2002-2005 Cable & Wireless <http://www.cw.com/>
@


1.7
log
@Adjusted copyright messages to include new year 2005.
@
text
@d182 1
a182 1
  dnl #   check for various implementations in priorized sequence   
@


1.6
log
@flush all my pending changes for release of 1.0.4
@
text
@d3 3
a5 3
dnl ##  Copyright (c) 2002-2004 Ralf S. Engelschall <rse@@engelschall.com>
dnl ##  Copyright (c) 2002-2004 The OSSP Project <http://www.ossp.org/>
dnl ##  Copyright (c) 2002-2004 Cable & Wireless <http://www.cw.com/>
@


1.5
log
@bump and adjust copyright
@
text
@d118 109
@


1.4
log
@final polishing
@
text
@d3 3
a5 3
dnl ##  Copyright (c) 2002-2003 Ralf S. Engelschall <rse@@engelschall.com>
dnl ##  Copyright (c) 2002-2003 The OSSP Project <http://www.ossp.org/>
dnl ##  Copyright (c) 2002-2003 Cable & Wireless Germany <http://www.cw.com/de/>
@


1.3
log
@- consistently use "Exception Handling"
- strip trailing whitespaces
- adjust copyright for new year 2003
- consistently use OSSP ASCII-art
@
text
@d5 1
a5 1
dnl ##  Copyright (c) 2002-2003 Cable & Wireless Deutschland <http://www.cw.com/de/>
@


1.2
log
@polishing
@
text
@d2 4
a5 4
dnl ##  OSSP ex - Exception Handling Library
dnl ##  Copyright (c) 2002 Ralf S. Engelschall <rse@@engelschall.com>
dnl ##  Copyright (c) 2002 The OSSP Project <http://www.ossp.org/>
dnl ##  Copyright (c) 2002 Cable & Wireless Deutschland <http://www.cw.com/de/>
@


1.1
log
@switch to our standard build environment
@
text
@d2 4
a5 4
dnl ##  SA - OSSP Socket Abstraction Library
dnl ##  Copyright (c) 2001-2002 Ralf S. Engelschall <rse@@engelschall.com>
dnl ##  Copyright (c) 2001-2002 The OSSP Project <http://www.ossp.org/>
dnl ##  Copyright (c) 2001-2002 Cable & Wireless Deutschland <http://www.cw.com/de/>
d7 2
a8 2
dnl ##  This file is part of OSSP SA, a socket abstraction library which
dnl ##  can be found at http://www.ossp.org/pkg/sa/.
@