head	1.9;
access;
symbols
	FSL_1_7_0:1.8
	CFG_0_9_11:1.8
	FSL_1_6_1:1.7
	CFG_0_9_10:1.7
	FSL_1_6_0:1.7
	FSL_1_6b2:1.7
	CFG_0_9_9:1.7
	FSL_1_6b1:1.7
	CFG_0_9_8:1.7
	CFG_0_9_7:1.5
	CFG_0_9_6:1.5
	CFG_0_9_5:1.5
	CFG_0_9_4:1.5
	FSL_1_5_0:1.4
	FSL_1_5a3:1.4
	CFG_0_9_3:1.4
	FSL_1_5a2:1.4
	FSL_1_5a1:1.4
	FSL_1_4_0:1.4
	FSL_1_4b1:1.4
	CFG_0_9_2:1.4
	CFG_0_9_1:1.4
	FSL_1_4a1:1.3
	FSL_1_3_0:1.3
	FSL_1_3b1:1.3
	FSL_1_2_1:1.3
	FSL_1_2_0:1.3
	FSL_1_1_0:1.3
	FSL_1_1b1:1.3
	FSL_1_0_8:1.3
	FSL_1_0_7:1.3
	FSL_1_0_6:1.1
	FSL_1_0_5:1.1
	FSL_1_0_4:1.1
	FSL_1_0_3:1.1
	FSL_1_0_2:1.1
	FSL_1_0_1:1.1
	FSL_1_0_0:1.1
	FSL_0_9_0:1.1
	CFG_0_9_0:1.1
	FSL_0_1_12:1.1
	FSL_0_1_11:1.1
	FSL_0_1_10:1.1
	FSL_0_1_9:1.1
	FSL_0_1_8:1.1
	FSL_0_1_7:1.1
	FSL_0_1_6:1.1
	FSL_0_1_5:1.1
	FSL_0_1_1:1.1;
locks; strict;
comment	@# @;


1.9
date	2007.10.12.21.02.48;	author rse;	state Exp;
branches;
next	1.8;
commitid	SLXuf5rAvHW8tlBs;

1.8
date	2006.08.10.19.35.56;	author rse;	state Exp;
branches;
next	1.7;
commitid	Isy241gp4yykKkIr;

1.7
date	2005.01.24.14.18.48;	author rse;	state Exp;
branches;
next	1.6;

1.6
date	2004.12.31.19.16.25;	author rse;	state Exp;
branches;
next	1.5;

1.5
date	2004.07.17.07.37.55;	author rse;	state Exp;
branches;
next	1.4;

1.4
date	2003.11.06.15.26.16;	author thl;	state Exp;
branches;
next	1.3;

1.3
date	2003.01.06.11.17.42;	author rse;	state Exp;
branches;
next	1.2;

1.2
date	2002.11.10.12.12.23;	author rse;	state Exp;
branches;
next	1.1;

1.1
date	2002.07.09.08.29.19;	author rse;	state Exp;
branches;
next	;


desc
@@


1.9
log
@Fix __VA_COPY_USE_{CSP,CPP} fallback macros for va_copy.

Submitted by: Mark A. Lindner <mark.a.lindner@@gmail.com>
@
text
@dnl ##
dnl ##  OSSP cfg - Configuration Parsing
dnl ##  Copyright (c) 2002-2006 Ralf S. Engelschall <rse@@engelschall.com>
dnl ##  Copyright (c) 2002-2006 The OSSP Project <http://www.ossp.org/>
dnl ##
dnl ##  This file is part of OSSP cfg, a configuration parsing library which
dnl ##  can be found at http://www.ossp.org/pkg/lib/cfg/.
dnl ##
dnl ##  Permission to use, copy, modify, and distribute this software for
dnl ##  any purpose with or without fee is hereby granted, provided that
dnl ##  the above copyright notice and this permission notice appear in all
dnl ##  copies.
dnl ##
dnl ##  THIS SOFTWARE IS PROVIDED ``AS IS'' AND ANY EXPRESSED OR IMPLIED
dnl ##  WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF
dnl ##  MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
dnl ##  IN NO EVENT SHALL THE AUTHORS AND COPYRIGHT HOLDERS AND THEIR
dnl ##  CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
dnl ##  SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
dnl ##  LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF
dnl ##  USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
dnl ##  ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
dnl ##  OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT
dnl ##  OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
dnl ##  SUCH DAMAGE.
dnl ##
dnl ##  aclocal.m4: GNU Autoconf local macro definitions
dnl ##

dnl ##
dnl ##  Check whether compiler option works
dnl ##
dnl ##  configure.in:
dnl ##    AC_COMPILER_OPTION(<name>, <display>, <option>,
dnl ##                       <action-success>, <action-failure>)
dnl ##

AC_DEFUN(AC_COMPILER_OPTION,[dnl
AC_MSG_CHECKING(whether compiler option(s) $2 work)
AC_CACHE_VAL(ac_cv_compiler_option_$1,[
SAVE_CFLAGS="$CFLAGS"
CFLAGS="$CFLAGS $3"
AC_TRY_COMPILE([],[], ac_cv_compiler_option_$1=yes, ac_cv_compiler_option_$1=no)
CFLAGS="$SAVE_CFLAGS"
])dnl
if test ".$ac_cv_compiler_option_$1" = .yes; then
    ifelse([$4], , :, [$4])
else
    ifelse([$5], , :, [$5])
fi
AC_MSG_RESULT([$ac_cv_compiler_option_$1])
])dnl

dnl ##
dnl ##  Debugging Support
dnl ##
dnl ##  configure.in:
dnl ##    AC_CHECK_DEBUGGING
dnl ##

AC_DEFUN(AC_CHECK_DEBUGGING,[dnl
AC_ARG_ENABLE(debug,dnl
[  --enable-debug          build for debugging (default=no)],
[dnl
if test ".$ac_cv_prog_gcc" = ".yes"; then
    case "$CFLAGS" in
        *-O* ) ;;
           * ) CFLAGS="$CFLAGS -O2" ;;
    esac
    case "$CFLAGS" in
        *-g* ) ;;
           * ) CFLAGS="$CFLAGS -g" ;;
    esac
    case "$CFLAGS" in
        *-pipe* ) ;;
              * ) AC_COMPILER_OPTION(pipe, -pipe, -pipe, CFLAGS="$CFLAGS -pipe") ;;
    esac
    AC_COMPILER_OPTION(defdbg, -DDEBUG, -DDEBUG, CFLAGS="$CFLAGS -DDEBUG")
    CFLAGS="$CFLAGS -pedantic"
    CFLAGS="$CFLAGS -Wall"
    WMORE=""
    WMORE="$WMORE -Wbad-function-cast"
    WMORE="$WMORE -Wcast-align"
    WMORE="$WMORE -Winline"
    WMORE="$WMORE -Wmissing-declarations"
    WMORE="$WMORE -Wmissing-prototypes"
    WMORE="$WMORE -Wmultichar"
    WMORE="$WMORE -Wnested-externs"
    WMORE="$WMORE -Wno-system-headers"
    WMORE="$WMORE -Wpointer-arith"
    WMORE="$WMORE -Wredundant-decls"
    WMORE="$WMORE -Wshadow"
    WMORE="$WMORE -Wstrict-prototypes"
    AC_COMPILER_OPTION(wmore, -W<xxx>, $WMORE, CFLAGS="$CFLAGS $WMORE")
else
    case "$CFLAGS" in
        *-g* ) ;;
           * ) CFLAGS="$CFLAGS -g" ;;
    esac
fi
msg="enabled"
],[
if test ".$ac_cv_prog_gcc" = ".yes"; then
case "$CFLAGS" in
    *-pipe* ) ;;
          * ) AC_COMPILER_OPTION(pipe, -pipe, -pipe, CFLAGS="$CFLAGS -pipe") ;;
esac
fi
case "$CFLAGS" in
    *-g* ) CFLAGS=`echo "$CFLAGS" |\
                   sed -e 's/ -g / /g' -e 's/ -g$//' -e 's/^-g //g' -e 's/^-g$//'` ;;
esac
case "$CXXFLAGS" in
    *-g* ) CXXFLAGS=`echo "$CXXFLAGS" |\
                     sed -e 's/ -g / /g' -e 's/ -g$//' -e 's/^-g //g' -e 's/^-g$//'` ;;
esac
msg=disabled
])dnl
AC_MSG_CHECKING(for compilation debug mode)
AC_MSG_RESULT([$msg])
if test ".$msg" = .enabled; then
    enable_shared=no
fi
])

dnl ##
dnl ##  Check for an external/extension library.
dnl ##  - is aware of <libname>-config style scripts
dnl ##  - searches under standard paths include, lib, etc.
dnl ##  - searches under subareas like .libs, etc.
dnl ##
dnl ##  configure.in:
dnl ##      AC_CHECK_EXTLIB(<realname>, <libname>, <func>, <header>,
dnl ##                      [<success-action> [, <fail-action>]])
dnl ##  Makefile.in:
dnl ##      CFLAGS  = @@CFLAGS@@
dnl ##      LDFLAGS = @@LDFLAGS@@
dnl ##      LIBS    = @@LIBS@@
dnl ##  shell:
dnl ##      $ ./configure --with-<libname>[=DIR]
dnl ##

AC_DEFUN(AC_CHECK_EXTLIB,[dnl
AC_ARG_WITH($2, [dnl
[  --with-]m4_substr([$2[[=DIR]]                     ], 0, 19)[build with external $1 library (default=no)]], [dnl
    if test ".$with_$2" = .yes; then
        #   via config script in PATH
        $2_version=`($2-config --version) 2>/dev/null`
        if test ".$$2_version" != .; then
            CPPFLAGS="$CPPFLAGS `$2-config --cflags`"
            CFLAGS="$CFLAGS `$2-config --cflags`"
            LDFLAGS="$LDFLAGS `$2-config --ldflags`"
        fi
    else
        if test -d "$with_$2"; then
            found=0
            #   via config script
            for dir in $with_$2/bin $with_$2; do
                if test -f "$dir/$2-config" && test ! -f "$dir/$2-config.in"; then
                    $2_version=`($dir/$2-config --version) 2>/dev/null`
                    if test ".$$2_version" != .; then
                        CPPFLAGS="$CPPFLAGS `$dir/$2-config --cflags`"
                        CFLAGS="$CFLAGS `$dir/$2-config --cflags`"
                        LDFLAGS="$LDFLAGS `$dir/$2-config --ldflags`"
                        found=1
                        break
                    fi
                fi
            done
            #   in standard sub-areas
            if test ".$found" = .0; then
                for dir in $with_$2/include/$2 $with_$2/include $with_$2; do
                    if test -f "$dir/$4"; then
                        CPPFLAGS="$CPPFLAGS -I$dir"
                        CFLAGS="$CFLAGS -I$dir"
                        found=1
                        break
                    fi
                done
                for dir in $with_$2/lib/$2 $with_$2/lib $with_$2; do
                    if test -f "$dir/lib$2.la" && test -d "$dir/.libs"; then
                        LDFLAGS="$LDFLAGS -L$dir -L$dir/.libs"
                        found=1
                        break
                    elif test -f "$dir/lib$2.a" || test -f "$dir/lib$2.so"; then
                        LDFLAGS="$LDFLAGS -L$dir"
                        found=1
                        break
                    fi
                done
            fi
            #   in any sub-area
            if test ".$found" = .0; then
changequote(, )dnl
                for file in x `find $with_$2 -name "$4" -type f -print`; do
                    test .$file = .x && continue
                    dir=`echo $file | sed -e 's;[^/]*$;;' -e 's;\(.\)/$;\1;'`
                    CPPFLAGS="$CPPFLAGS -I$dir"
                    CFLAGS="$CFLAGS -I$dir"
                done
                for file in x `find $with_$2 -name "lib$2.[aso]" -type f -print`; do
                    test .$file = .x && continue
                    dir=`echo $file | sed -e 's;[^/]*$;;' -e 's;\(.\)/$;\1;'`
                    LDFLAGS="$LDFLAGS -L$dir"
                done
changequote([, ])dnl
            fi
        fi
    fi
    AC_HAVE_HEADERS($4)
    AC_CHECK_LIB($2, $3)
    with_$2=yes
    ac_var="ac_cv_header_`echo $4 | sed 'y%./+-%__p_%'`"
    eval "ac_val=\$$ac_var"
    if test ".$ac_val" != .yes; then
        with_$2=no
    fi
    if test ".$ac_cv_lib_$2_$3" != .yes; then
        with_$2=no
    fi
    if test ".$with_$2" = .no; then
        AC_ERROR([Unable to find $1 library])
    fi
    ], [dnl
if test ".$with_$2" = .; then
    with_$2=no
fi
    ])dnl
AC_MSG_CHECKING(whether to build against external $1 library)
if test ".$with_$2" = .yes; then
    ifelse([$5], , :, [$5])
else
    ifelse([$6], , :, [$6])
fi
AC_MSG_RESULT([$with_$2])
])dnl

dnl ##
dnl ##  Check for GNU Bison and GNU Flex
dnl ##
dnl ##  configure.in:
dnl ##      AC_CHECK_BISON(BISON, 1.30, [1.3[0-9]|1.[4-9]])
dnl ##      AC_CHECK_FLEX(FLEX, 2.5.6, [2.5.[6-9]|2.5.1[0-9]|2.[6-9].*])
dnl ##
dnl ##  Makefile.in:
dnl ##      BISON = @@BISON@@
dnl ##      FLEX  = @@FLEX@@
dnl ##

AC_DEFUN(AC_CHECK_BISON,[dnl
if test ".$enable_maintainer" = .yes; then
    bison_version=""
    for prog in bison bison-beta bison-alpha bison-snap; do
        AC_PATH_PROG($1, $prog, NA)
        if test ".$$1" != .NA; then
            bison_version=`($$1 --version | head -1 | sed -e 's;^[[^0-9]]*\([[0-9]][[0-9.]]*\).*;\1;') 2>/dev/null`
            case "$bison_version" in
                $3 ) break ;;
                * ) $1="NA"; unset ac_cv_path_$1 ;;
            esac
        else
            unset ac_cv_path_$1
        fi
    done
    if test ".$$1" = .NA; then
        if test ".$bison_version" != .; then
            AC_ERROR([found GNU Bison version $bison_version; require version >= $2])
        else
            AC_ERROR([require GNU Bison version >= $2])
        fi
    fi
else
    dnl # disable the use of the tools, but still allow manual override
    test ".$$1" = . && $1=true
    AC_PATH_PROG($1, bison, true)
fi
])

AC_DEFUN(AC_CHECK_FLEX,[dnl
if test ".$enable_maintainer" = .yes; then
    flex_version=""
    for prog in flex flex-beta flex-alpha flex-snap; do
        AC_PATH_PROG($1, $prog, NA)
        if test ".$$1" != .NA; then
            flex_version=`($$1 --version | head -1 | sed -e 's;^[[^0-9]]*\([[0-9]][[0-9.]]*\).*;\1;') 2>/dev/null`
            case "$flex_version" in
                $3 ) break ;;
                * ) $1="NA"; unset ac_cv_path_$1 ;;
            esac
        else
            unset ac_cv_path_$1
        fi
    done
    if test ".$$1" = .NA; then
        if test ".$flex_version" != .; then
            AC_ERROR([found GNU Flex version $flex_version; require version >= $2])
        else
            AC_ERROR([require GNU Flex version >= $2])
        fi
    fi
else
    test ".$$1" = . && $1=true
    AC_PATH_PROG($1, flex, true)
fi
])

dnl ##
dnl ##  Check for C99 va_copy() implementation
dnl ##  (and provide fallback implementation if neccessary)
dnl ##
dnl ##  configure.in:
dnl ##    AC_CHECK_VA_COPY
dnl ##  foo.c:
dnl ##    #include "config.h"
dnl ##    [...]
dnl ##    va_copy(d,s)
dnl ##
dnl ##  This check is rather complex: first because we really have to
dnl ##  try various possible implementations in sequence and second, we
dnl ##  cannot define a macro in config.h with parameters directly.
dnl ##

dnl #   test program for va_copy() implementation
changequote(<<,>>)
m4_define(__va_copy_test, <<[
#include <stdlib.h>
#include <stdarg.h>
#include <string.h>
#define DO_VA_COPY(d, s) $1
void test(char *str, ...)
{
    va_list ap, ap2;
    int i;
    va_start(ap, str);
    DO_VA_COPY(ap2, ap);
    for (i = 1; i <= 9; i++) {
        int k = (int)va_arg(ap, int);
        if (k != i)
            abort();
    }
    DO_VA_COPY(ap, ap2);
    for (i = 1; i <= 9; i++) {
        int k = (int)va_arg(ap, int);
        if (k != i)
            abort();
    }
    va_end(ap);
}
int main(int argc, char *argv[])
{
    test("test", 1, 2, 3, 4, 5, 6, 7, 8, 9);
    exit(0);
}
]>>)
changequote([,])

dnl #   test driver for va_copy() implementation
m4_define(__va_copy_check, [
    AH_VERBATIM($1,
[/* Predefined possible va_copy() implementation (id: $1) */
#define __VA_COPY_USE_$1(d, s) $2])
    if test ".$ac_cv_va_copy" = .; then
        AC_TRY_RUN(__va_copy_test($2), [ac_cv_va_copy="$1"])
    fi
])

dnl #   Autoconf check for va_copy() implementation checking
AC_DEFUN(AC_CHECK_VA_COPY,[
  dnl #   provide Autoconf display check message
  AC_MSG_CHECKING(for va_copy() function)
  dnl #   check for various implementations in priorized sequence   
  AC_CACHE_VAL(ac_cv_va_copy, [
    ac_cv_va_copy=""
    dnl #   1. check for standardized C99 macro
    __va_copy_check(C99, [va_copy((d), (s))])
    dnl #   2. check for alternative/deprecated GCC macro
    __va_copy_check(GCM, [VA_COPY((d), (s))])
    dnl #   3. check for internal GCC macro (high-level define)
    __va_copy_check(GCH, [__va_copy((d), (s))])
    dnl #   4. check for internal GCC macro (built-in function)
    __va_copy_check(GCB, [__builtin_va_copy((d), (s))])
    dnl #   5. check for assignment approach (assuming va_list is a struct)
    __va_copy_check(ASS, [do { (d) = (s); } while (0)])
    dnl #   6. check for assignment approach (assuming va_list is a pointer)
    __va_copy_check(ASP, [do { *(d) = *(s); } while (0)])
    dnl #   7. check for memory copying approach (assuming va_list is a struct)
    __va_copy_check(CPS, [memcpy((void *)&(d), (void *)&(s), sizeof((s)))])
    dnl #   8. check for memory copying approach (assuming va_list is a pointer)
    __va_copy_check(CPP, [memcpy((void *)(d), (void *)(s), sizeof(*(s)))])
    if test ".$ac_cv_va_copy" = .; then
        AC_ERROR([no working implementation found])
    fi
  ])
  dnl #   optionally activate the fallback implementation
  if test ".$ac_cv_va_copy" = ".C99"; then
      AC_DEFINE(HAVE_VA_COPY, 1, [Define if va_copy() macro exists (and no fallback implementation is required)])
  fi
  dnl #   declare which fallback implementation to actually use
  AC_DEFINE_UNQUOTED([__VA_COPY_USE], [__VA_COPY_USE_$ac_cv_va_copy],
      [Define to id of used va_copy() implementation])
  dnl #   provide activation hook for fallback implementation
  AH_VERBATIM([__VA_COPY_ACTIVATION],
[/* Optional va_copy() implementation activation */
#ifndef HAVE_VA_COPY
#define va_copy(d, s) __VA_COPY_USE(d, s)
#endif
])
  dnl #   provide Autoconf display result message
  if test ".$ac_cv_va_copy" = ".C99"; then
      AC_MSG_RESULT([yes])
  else
      AC_MSG_RESULT([no (using fallback implementation)])
  fi
])

@


1.8
log
@cleanup source tree for status as of 2006
@
text
@d387 1
a387 1
    __va_copy_check(CPS, [memcpy((void *)&(d), (void *)&(s)), sizeof((s))])
d389 1
a389 1
    __va_copy_check(CPP, [memcpy((void *)(d), (void *)(s)), sizeof(*(s))])
@


1.7
log
@1. Fix va_list variable passing in cfg_fmt functions.
2. Add Autoconf support for va_copy() detection.
3. Accept new GNU Bison 2.0 as parser generator.
@
text
@d3 2
a4 3
dnl ##  Copyright (c) 2002-2005 Ralf S. Engelschall <rse@@engelschall.com>
dnl ##  Copyright (c) 2002-2005 The OSSP Project <http://www.ossp.org/>
dnl ##  Copyright (c) 2002-2005 Cable & Wireless <http://www.cw.com/>
@


1.6
log
@Adjust copyright messages for new year 2005.
@
text
@d308 109
@


1.5
log
@Adjust copyright messages for new year 2004.
@
text
@d3 3
a5 3
dnl ##  Copyright (c) 2002-2004 Ralf S. Engelschall <rse@@engelschall.com>
dnl ##  Copyright (c) 2002-2004 The OSSP Project <http://www.ossp.org/>
dnl ##  Copyright (c) 2002-2004 Cable & Wireless <http://www.cw.com/>
@


1.4
log
@reorganize compiler warning options for easier comparison with other packages; remove traditional
@
text
@d3 3
a5 3
dnl ##  Copyright (c) 2002-2003 Ralf S. Engelschall <rse@@engelschall.com>
dnl ##  Copyright (c) 2002-2003 The OSSP Project <http://www.ossp.org/>
dnl ##  Copyright (c) 2002-2003 Cable & Wireless Deutschland <http://www.cw.com/de/>
@


1.3
log
@update copyright messages for new year
@
text
@d82 13
a94 5
    WMORE="-Wmultichar -Wno-system-headers -Wtraditional"
    WMORE="$WMORE -Wshadow -Wpointer-arith"
    WMORE="$WMORE -Wbad-function-cast -Wcast-align"
    WMORE="$WMORE -Wstrict-prototypes -Wmissing-prototypes -Wmissing-declarations"
    WMORE="$WMORE -Wredundant-decls -Wnested-externs -Winline"
@


1.2
log
@remove trailing whitespaces
@
text
@d3 3
a5 3
dnl ##  Copyright (c) 2002 Ralf S. Engelschall <rse@@engelschall.com>
dnl ##  Copyright (c) 2002 The OSSP Project <http://www.ossp.org/>
dnl ##  Copyright (c) 2002 Cable & Wireless Deutschland <http://www.cw.com/de/>
@


1.1
log
@add standard OSSP autoconf/libtool/shtool environment
@
text
@d247 1
a247 1
        AC_PATH_PROG($1, $prog, NA) 
d276 1
a276 1
        AC_PATH_PROG($1, $prog, NA) 
@